SPARQL 1.2 질의 언어

절 제목에 달리 명시되지 않는 한, 이 문서의 모든 절과 부록은 규범적입니다.

이 문서의 이 절인 1절은 SPARQL 질의 언어 명세를 소개합니다. 이 명세 문서의 구성과 명세 전반에서 사용되는 규약을 제시합니다.

명세의 2절은 일련의 예제 질의와 질의 결과를 통해 SPARQL 질의 언어 자체를 소개합니다. 3절은 질의 결과에 나타나는 RDF 용어에 대한 제약을 표현하는 SPARQL의 능력을 보여 주는 더 많은 예제로 SPARQL 질의 언어 소개를 이어갑니다.

4절은 SPARQL 질의 언어의 구문 세부 사항을 제시합니다. 이는 언어의 전체 문법에 대한 동반 설명이며, 문법적 구성 요소가 IRI, 빈 노드, 리터럴 및 변수를 어떻게 표현하는지를 정의합니다. 또한 4절은 더 장황한 표현을 위한 구문적 설탕 역할을 하는 여러 문법적 구성 요소의 의미도 정의합니다.

5절은 더 복잡한 SPARQL 질의 패턴을 구성하는 빌딩 블록인 기본 그래프 패턴과 그룹 그래프 패턴을 소개합니다. 6, 7, 8절은 SPARQL 그래프 패턴을 더 큰 그래프 패턴으로 결합하는 구성 요소를 제시합니다. 특히 6절은 질의의 일부를 선택적으로 만드는 기능을 소개하고, 7절은 대안 그래프 패턴의 분리를 표현하는 기능을 소개하며, 8절은 정보의 부재를 테스트하는 패턴을 소개합니다.

9절은 그래프 패턴 일치에 속성 경로를 추가하여, 질의의 간결한 표현과 그래프에서 임의 길이 경로를 일치시키는 기능을 제공합니다.

10절은 SPARQL에서 가능한 할당 형식을 설명합니다.

11절은 결과를 그룹화하고 집계하는 메커니즘을 소개하며, 이는 12절에서 설명하는 하위 질의로 포함될 수 있습니다.

13절은 질의의 일부를 특정 소스 그래프로 제한하는 기능을 소개합니다. 또한 13절은 질의를 위한 소스 그래프를 정의하는 SPARQL의 메커니즘도 제시합니다.

14절은 별도의 문서인 SPARQL 1.1 Federated Query를 참조합니다.

15절은 해의 시퀀스를 정렬, 슬라이싱, 투영, 제한하고 중복을 제거함으로써 질의의 해에 영향을 주는 구성 요소를 정의합니다.

16절은 서로 다른 형식으로 결과를 산출하는 네 가지 유형의 SPARQL 질의를 정의합니다.

17절은 SPARQL의 확장 가능한 값 테스트 및 표현식 프레임워크를 정의합니다. 질의 결과에 나타나는 값을 제약하고, 질의가 반환할 새 값을 계산하는 데 사용할 수 있는 함수와 연산자를 제시합니다.

18절은 SPARQL 그래프 패턴과 해 수정자의 평가에 대한 형식적 정의입니다.

19절은 EBNF 표기법으로 표현된 문법에 따라 주어진 SPARQL 질의와 SPARQL 1.1 Update 언어 구문의 규범적 정의를 포함합니다.

아래 예제는 주어진 데이터 그래프에서 책의 제목을 찾는 SPARQL 질의를 보여 줍니다. 질의는 두 부분으로 구성됩니다. SELECT 절은 질의 결과에 나타날 변수를 식별하고, WHERE 절은 데이터 그래프와 일치시킬 기본 그래프 패턴을 제공합니다. 이 예제의 기본 그래프 패턴은 목적어 위치에 하나의 변수(?title)가 있는 단일 트리플 패턴으로 구성됩니다.

<http://example.org/book/book1> <http://purl.org/dc/elements/1.1/title> "SPARQL Tutorial" .

SELECT ?title
WHERE
{
    <http://example.org/book/book1> <http://purl.org/dc/elements/1.1/title> ?title .
}

질의의 결과는 해 시퀀스이며, 질의의 그래프 패턴이 데이터와 일치하는 방식에 해당합니다. 질의에는 0개, 1개 또는 여러 개의 해가 있을 수 있습니다.

데이터:

PREFIX foaf:  <http://xmlns.com/foaf/0.1/> .

_:a  foaf:name   "Johnny Lee Outlaw" .
_:a  foaf:mbox   <mailto:jlow@example.com> .
_:b  foaf:name   "Peter Goodguy" .
_:b  foaf:mbox   <mailto:peter@example.org> .
_:c  foaf:mbox   <mailto:carol@example.org> .

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE
{ ?x foaf:name ?name .
  ?x foaf:mbox ?mbox }

각 해는 선택된 변수가 RDF 용어에 바인딩되어 질의 패턴이 데이터와 일치할 수 있는 하나의 방식을 제공합니다. 결과 집합은 가능한 모든 해를 제공합니다. 위 예제에서는 제공된 데이터의 다음 두 부분집합이 두 개의 일치를 제공했습니다.

_:a foaf:name  "Johnny Lee Outlaw" .
_:a foaf:box   <mailto:jlow@example.com> .

_:b foaf:name  "Peter Goodguy" .
_:b foaf:box   <mailto:peter@example.org> .

이는 기본 그래프 패턴 일치입니다. 질의 패턴에서 사용되는 모든 변수는 모든 해에서 반드시 바인딩되어야 합니다.

아래 데이터에는 세 개의 RDF 리터럴이 포함되어 있습니다.

PREFIX dt:   <http://example.org/datatype#>
PREFIX ns:   <http://example.org/ns#>
PREFIX :     <http://example.org/ns#>
PREFIX xsd:  <http://www.w3.org/2001/XMLSchema#>

:x   ns:p     "cat"@en .
:y   ns:p     "42"^^xsd:integer .
:z   ns:p     "abc"^^dt:specialDatatype .

이 RDF 데이터는 2.3.1–2.3.3절의 질의 예제에 대한 데이터 그래프입니다.

SELECT ?v WHERE { ?v ?p "cat" }

SELECT ?v WHERE { ?v ?p "cat"@en }

SELECT ?v WHERE { ?v ?p 42 }

SELECT ?v WHERE { ?v ?p "abc"^^<http://example.org/datatype#specialDatatype> }

질의 결과에는 빈 노드가 포함될 수 있습니다. 이 문서의 예제 결과 집합에서 빈 노드는 "_:" 뒤에 빈 노드 식별자가 오는 형식으로 작성됩니다.

빈 노드 식별자는 결과 집합("SPARQL Query Results XML Format (Second Edition)" 및 "SPARQL 1.1 Query Results JSON Format" 참조) 또는 CONSTRUCT 질의 형식의 경우 결과 그래프를 범위로 합니다. 결과 집합 내에서 같은 식별자를 사용하면 같은 빈 노드를 나타냅니다.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>

_:a  foaf:name   "Alice" .
_:b  foaf:name   "Bob" .

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
SELECT ?x ?name
WHERE  { ?x foaf:name ?name }

이 두 결과는 같은 정보를 가집니다. 질의와 일치하는 데 사용된 빈 노드는 두 해에서 서로 다릅니다. 결과 집합의 빈 노드 식별자 _:a와 데이터 구문에서 사용된 빈 노드 식별자 사이에는 어떤 관계도 있을 필요가 없습니다.

애플리케이션 작성자는 질의의 빈 노드 식별자가 데이터의 특정 빈 노드를 참조한다고 기대해서는 안 됩니다.

SPARQL 1.2는 복잡한 표현식에서 값을 만들 수 있게 합니다. 아래 질의는 CONCAT 함수를 사용하여 FOAF 데이터에서 이름과 성을 연결한 다음, SELECT 절의 표현식을 사용해 값을 할당하고, 또한 BIND 형식을 사용해 값을 할당하는 방법을 보여 줍니다.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
            
_:a  foaf:givenName   "John" .
_:a  foaf:surname  "Doe" .

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
SELECT ( CONCAT(?G, " ", ?S) AS ?name )
WHERE  { ?P foaf:givenName ?G ; foaf:surname ?S }

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
SELECT ?name
WHERE  { 
    ?P foaf:givenName ?G ; 
       foaf:surname ?S 
    BIND(CONCAT(?G, " ", ?S) AS ?name)
}

SPARQL에는 여러 질의 형식이 있습니다. SELECT 질의 형식은 변수 바인딩을 반환합니다. CONSTRUCT 질의 형식은 RDF 그래프를 반환합니다. 그래프는 질의의 그래프 패턴 일치 결과를 바탕으로 RDF 트리플을 생성하는 데 사용되는 템플릿을 기반으로 구축됩니다.

PREFIX org:    <http://example.com/ns#>

_:a  org:employeeName   "Alice" .
_:a  org:employeeId     12345 .

_:b  org:employeeName   "Bob" .
_:b  org:employeeId     67890 .

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
PREFIX org:    <http://example.com/ns#>

CONSTRUCT { ?x foaf:name ?name }
WHERE  { ?x org:employeeName ?name }

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
                
_:x foaf:name "Alice" .
_:y foaf:name "Bob" .

<rdf:RDF
   xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
   xmlns:foaf="http://xmlns.com/foaf/0.1/" >

  <rdf:Description>
    <foaf:name>Alice</foaf:name>
  </rdf:Description>
  <rdf:Description>
    <foaf:name>Bob</foaf:name>
  </rdf:Description>
</rdf:RDF>

regex와 같은 SPARQL FILTER 함수는 RDF 리터럴을 테스트할 수 있습니다. regex는 문자열 리터럴에만 일치합니다. regex는 str 함수를 사용하여 다른 리터럴의 어휘 형식과 일치시키는 데 사용할 수 있습니다.

질의:

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
SELECT  ?title
WHERE   { 
    ?x dc:title ?title
    FILTER regex(?title, "^SPARQL") 
}

정규식 일치는 "i" 플래그로 대소문자를 구분하지 않도록 만들 수 있습니다.

질의:

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
SELECT  ?title
WHERE   { 
    ?x dc:title ?title
    FILTER regex(?title, "web", "i" ) 
}

정규식 언어는 XQuery 및 XPath Functions and Operators에서 정의되며 XML Schema 정규식을 기반으로 합니다.

SPARQL FILTER는 산술 표현식에 대해 제한할 수 있습니다.

질의:

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
PREFIX  ns:  <http://example.org/ns#>

SELECT  ?title ?price
WHERE   {
    ?x ns:price ?price .
    FILTER (?price < 30.5)
    ?x dc:title ?title . 
}

숫자 타입 외에도 SPARQL은 xsd:string, xsd:boolean 및 xsd:dateTime 타입을 지원합니다 (피연산자 데이터 타입 참조). 연산자 매핑 절은 연산자를 설명하고, 함수 정의 절은 RDF 용어에 적용할 수 있는 함수를 설명합니다.

트리플 패턴은 주어, 술어 및 객체로 작성됩니다. 일부 일반적인 트리플 패턴 구성 요소를 작성하는 축약 방법이 있습니다.

다음 예제들은 동일한 질의를 표현합니다.

PREFIX  dc: <http://purl.org/dc/elements/1.1/>
SELECT  ?title
WHERE   { <http://example.org/book/book1> dc:title ?title }

PREFIX  dc: <http://purl.org/dc/elements/1.1/>
PREFIX  : <http://example.org/book/>

SELECT  $title
WHERE   { :book1  dc:title  $title }

BASE    <http://example.org/book/>
PREFIX  dc: <http://purl.org/dc/elements/1.1/>

SELECT  $title
WHERE   { <book1>  dc:title  ?title }

?x  foaf:name  ?name ;
foaf:mbox  ?mbox .

?x  foaf:name  ?name .
?x  foaf:mbox  ?mbox .

?x foaf:nick  "Alice" , "Alice_" .

?x  foaf:nick  "Alice" .
?x  foaf:nick  "Alice_" .

?x  foaf:name ?name ; foaf:nick  "Alice" , "Alice_" .

?x  foaf:name  ?name .
?x  foaf:nick  "Alice" .
?x  foaf:nick  "Alice_" .

(1 ?x 3 4) :p "w" .

_:b0  rdf:first  1 ;
      rdf:rest   _:b1 .
_:b1  rdf:first  ?x ;
      rdf:rest   _:b2 .
_:b2  rdf:first  3 ;
      rdf:rest   _:b3 .
_:b3  rdf:first  4 ;
      rdf:rest   rdf:nil .
_:b0  :p         "w" .

(1 [:p :q] ( 2 ) ) .

_:b0  rdf:first  1 ;
      rdf:rest   _:b1 .
_:b1  rdf:first  _:b2 .
_:b2  :p         :q .
_:b1  rdf:rest   _:b3 .
_:b3  rdf:first  _:b4 .
_:b4  rdf:first  2 ;
      rdf:rest   rdf:nil .
_:b3  rdf:rest   rdf:nil .

?x  a  :Class1 .
[ a :appClass ] :p "v" .

?x    rdf:type  :Class1 .
_:b0  rdf:type  :appClass .
_:b0  :p        "v" .

SPARQL의 언어 진화에 대응하기 위해 VERSION 지시자를 사용할 수 있습니다. 트리플 용어 또는 트리플 용어에 대한 함수와 같은 새 기능이 포함된 SPARQL 질의를 작성할 때, 작성자는 이 지시자를 포함하고 포함된 기능을 처리하는 데 필요한 버전을 나타내는 버전 레이블을 뒤따르게 함으로써 새 구문 형식의 사용을 선언할 수 있습니다.

버전 레이블은 다음 절에서 정의됩니다. 처리기는 인식할 수 없는 레이블을 오류 또는 경고로 처리할 수 있습니다.

VERSION "1.2"
PREFIX : <http://example/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?s ?date {
    ?s ?p ?o .
    BIND( <<( ?s ?p ?o )>> AS ?tt )
    :myreifier rdf:reifies ?tt .
    :myreifier :tripleAdded ?date .
}

SPARQL 1.2 프로토콜도 버전 알림을 미디어 타입의 version 매개변수를 사용해 제공한다. 이는 VERSION 지시어가 없는 경우 고려된다.

기본 그래프 패턴은 트리플 패턴의 집합입니다. SPARQL 그래프 패턴 일치는 기본 그래프 패턴을 일치시킨 결과를 결합하는 방식으로 정의됩니다.

선택적 필터가 있는 트리플 패턴의 시퀀스는 하나의 기본 그래프 패턴을 구성합니다. 다른 모든 그래프 패턴은 기본 그래프 패턴을 종료합니다.

SPARQL 질의 문자열에서 그룹 그래프 패턴은 중괄호 {}로 구분됩니다. 예를 들어 이 질의의 질의 패턴은 하나의 기본 그래프 패턴으로 이루어진 그룹 그래프 패턴입니다.

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE  {
    ?x foaf:name ?name .
    ?x foaf:mbox ?mbox .
}

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE  { 
   { ?x foaf:name ?name . }
   { ?x foaf:mbox ?mbox . }
}

{ }

SELECT ?x
WHERE {}

{  ?x foaf:name ?name .
   ?x foaf:mbox ?mbox .
   FILTER regex(?name, "Smith")
}

{  FILTER regex(?name, "Smith")
   ?x foaf:name ?name .
   ?x foaf:mbox ?mbox .
}

{  ?x foaf:name ?name .
   FILTER regex(?name, "Smith")
   ?x foaf:mbox ?mbox .
}

{ ?x foaf:name ?name .
  ?x foaf:mbox ?mbox .
}

{
  ?x foaf:name ?name . FILTER regex(?name, "Smith")
  ?x foaf:mbox ?mbox .
}

{
  ?x foaf:name ?name .
  {}
  ?x foaf:mbox ?mbox .
}

그래프 패턴의 선택적 부분은 그래프 패턴에 OPTIONAL 키워드를 적용하여 구문적으로 지정할 수 있습니다.

pattern OPTIONAL { pattern }

{ OPTIONAL { pattern } }

{ { } OPTIONAL { pattern } }

pattern OPTIONAL { pattern } OPTIONAL { pattern }

{ pattern OPTIONAL { pattern } } OPTIONAL { pattern }

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>
PREFIX rdf:        <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

_:a  rdf:type        foaf:Person .
_:a  foaf:name       "Alice" .
_:a  foaf:mbox       <mailto:alice@example.com> .
_:a  foaf:mbox       <mailto:alice@work.example> .

_:b  rdf:type        foaf:Person .
_:b  foaf:name       "Bob" .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE  {
    ?x foaf:name  ?name .
    OPTIONAL { ?x  foaf:mbox  ?mbox }
}

이름이 "Bob"인 해에는 mbox 값이 없습니다.

이 질의는 데이터에 있는 사람들의 이름을 찾습니다. 술어가 mbox이고 주어가 같은 트리플이 있으면, 해는 그 트리플의 객체도 포함합니다. 이 예제에서는 질의의 선택적 일치 부분에 단일 트리플 패턴만 주어져 있지만, 일반적으로 선택적 부분은 어떤 그래프 패턴도 될 수 있습니다. 선택적 그래프 패턴이 질의 해에 영향을 주려면 전체 선택적 그래프 패턴이 일치해야 합니다.

선택적 그래프 패턴 안에 제약을 줄 수 있습니다. 예를 들면 다음과 같습니다.

PREFIX dc:   <http://purl.org/dc/elements/1.1/>
PREFIX :     <http://example.org/book/>
PREFIX ns:   <http://example.org/ns#>

:book1  dc:title  "SPARQL Tutorial" .
:book1  ns:price  42 .
:book2  dc:title  "The Semantic Web" .
:book2  ns:price  23 .

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
PREFIX  ns:  <http://example.org/ns#>
SELECT  ?title ?price
WHERE   { 
    ?x dc:title ?title .
    OPTIONAL { ?x ns:price ?price . FILTER (?price < 30) }
}

제목이 "SPARQL Tutorial"인 책에 가격이 나타나지 않는 이유는 선택적 그래프 패턴이 변수 "price"를 포함하는 해로 이어지지 않았기 때문입니다.

그래프 패턴은 재귀적으로 정의됩니다. 그래프 패턴은 0개 이상의 선택적 그래프 패턴을 가질 수 있으며, 질의 패턴의 어떤 부분도 선택적 부분을 가질 수 있습니다. 이 예제에는 두 개의 선택적 그래프 패턴이 있습니다.

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>

_:a  foaf:name       "Alice" .
_:a  foaf:homepage   <http://work.example.org/alice/> .

_:b  foaf:name       "Bob" .
_:b  foaf:mbox       <mailto:bob@work.example> .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox ?hpage
WHERE  {
    ?x foaf:name  ?name .
    OPTIONAL { ?x foaf:mbox ?mbox } .
    OPTIONAL { ?x foaf:homepage ?hpage }
}

질의 해의 필터링은 FILTER 표현식 안에서 NOT EXISTS와 EXISTS를 사용하여 수행됩니다. 필터 범위 규칙은 필터가 나타나는 전체 그룹에 적용된다는 점에 유의하십시오.

PREFIX  :       <http://example/>
PREFIX  rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  foaf:   <http://xmlns.com/foaf/0.1/>

:alice  rdf:type   foaf:Person .
:alice  foaf:name  "Alice" .
:bob    rdf:type   foaf:Person .

PREFIX  rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX  foaf:   <http://xmlns.com/foaf/0.1/> 

SELECT ?person
WHERE 
{
    ?person rdf:type  foaf:Person .
    FILTER NOT EXISTS { ?person foaf:name ?name }
}

PREFIX  rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX  foaf:   <http://xmlns.com/foaf/0.1/> 

SELECT ?person
WHERE {
    ?person rdf:type  foaf:Person .
    FILTER EXISTS { ?person foaf:name ?name }
}

SPARQL에서 제공되는 다른 방식의 부정은 MINUS입니다. 이는 두 인자를 모두 평가한 다음, 왼쪽의 해 중 오른쪽의 해와 호환되지 않는 해를 계산합니다.

PREFIX :       <http://example/>
PREFIX foaf:   <http://xmlns.com/foaf/0.1/>

:alice  foaf:givenName "Alice" ;
        foaf:familyName "Smith" .

:bob    foaf:givenName "Bob" ;
        foaf:familyName "Jones" .

:carol  foaf:givenName "Carol" ;
        foaf:familyName "Smith" .

PREFIX :       <http://example/>
PREFIX foaf:   <http://xmlns.com/foaf/0.1/>

SELECT DISTINCT ?s
WHERE {
    ?s ?p ?o .
    MINUS {
        ?s foaf:givenName "Bob" .
    }
}

NOT EXISTS와 MINUS는 부정을 생각하는 두 가지 방식을 나타냅니다. 하나는 질의 패턴에서 이미 결정된 바인딩이 주어졌을 때 패턴이 데이터에 존재하는지 테스트하는 방식이고, 다른 하나는 두 패턴의 평가를 바탕으로 일치를 제거하는 방식입니다. 어떤 경우에는 서로 다른 답을 생성할 수 있습니다.

PREFIX : <http://example/>
:a :b :c .

SELECT * { 
    ?s ?p ?o
    FILTER NOT EXISTS { ?x ?y ?z }
}

SELECT * { 
    ?s ?p ?o 
    MINUS 
    { ?x ?y ?z }
}

PREFIX : <http://example/>
SELECT * {  
    ?s ?p ?o 
    FILTER NOT EXISTS { :a :b :c }
}

PREFIX : <http://example/>
SELECT * 
{ 
    ?s ?p ?o 
    MINUS { :a :b :c }
}

PREFIX : <http://example.com/>
:a :p 1 .
:a :q 1 .
:a :q 2 .

:b :p 3.0 .
:b :q 4.0 .
:b :q 5.0 .

PREFIX : <http://example.com/>
SELECT * WHERE {
    ?x :p ?n
    FILTER NOT EXISTS {
        ?x :q ?m .
        FILTER(?n = ?m)
    }
}

PREFIX : <http://example/>
SELECT * WHERE {
    ?x :p ?n
    MINUS {
        ?x :q ?m .
        FILTER(?n = ?m)
    }
}

아래 설명에서 iri는 전체로 작성되거나 접두 이름으로 축약된 IRI 또는 키워드 a입니다. elt는 경로 요소이며, 그 자체가 경로 구성 요소로 이루어질 수 있습니다.

부정된 속성 집합에서 IRI와 역방향 IRI의 순서는 중요하지 않으며, 서로 섞인 순서로 나타날 수 있습니다.

구문 형식의 우선순위는 높은 것부터 낮은 것까지 다음과 같습니다.

• IRI, 접두 이름
• 부정된 속성 집합
• 그룹
• 단항 연산자 *, ? 및 +
• 단항 ^ 역방향 링크
• 이항 연산자 /
• 이항 연산자 |

우선순위는 그룹 내에서 왼쪽에서 오른쪽입니다.

대안: 하나 또는 두 가능성 모두와 일치

{ :book1 dc:title|rdfs:label ?displayString }

이는 다음과 같이 작성할 수도 있습니다.

{ 
   :book1 <http://purl.org/dc/elements/1.1/title> | <http://www.w3.org/2000/01/rdf-schema#label> ?displayString
}

시퀀스: Alice가 아는 사람들의 이름 찾기.

{
    ?x foaf:mbox <mailto:alice@example> .
    ?x foaf:knows/foaf:name ?name .
}

시퀀스: "foaf:knows" 링크 두 단계 떨어진 사람들의 이름 찾기.

{ 
    ?x foaf:mbox <mailto:alice@example> .
    ?x foaf:knows/foaf:knows/foaf:name ?name .
}

이는 다음 SPARQL 질의와 같습니다.

SELECT ?x ?name {
    ?x  foaf:mbox <mailto:alice@example> .
    ?x  foaf:knows [ foaf:knows [ foaf:name ?name ]]. 
}

또는 명시적 변수를 사용하면 다음과 같습니다.

SELECT ?x ?name {
    ?x  foaf:mbox <mailto:alice@example> .
    ?x  foaf:knows ?a1 .
    ?a1 foaf:knows ?a2 .
    ?a2 foaf:name ?name .
}

중복 필터링: Alice가 아는 사람이 Alice 자신을 알고 있을 수도 있으므로, 위 예제에는 Alice 자신이 포함될 수 있습니다. 이는 다음으로 피할 수 있습니다.

{ ?x foaf:mbox <mailto:alice@example> .
  ?x foaf:knows/foaf:knows ?y .
  FILTER ( ?x != ?y )
  ?y foaf:name ?name 
}

역방향 속성 경로: 다음 두 질의는 같습니다. 두 번째는 속성 방향을 반대로 하여 주어와 객체의 역할을 바꾼 것뿐입니다.

{ ?x foaf:mbox <mailto:alice@example> }

{ <mailto:alice@example> ^foaf:mbox ?x }

역방향 경로 시퀀스: ?x가 아는 어떤 사람을 아는 모든 사람 찾기.

{
  ?x foaf:knows/^foaf:knows ?y .  
  FILTER(?x != ?y)
}

이는 다음과 동등합니다(?gen1은 시스템이 생성한 변수입니다).

{
  ?x foaf:knows ?gen1 .
  ?y foaf:knows ?gen1 .  
  FILTER(?x != ?y)
}

임의 길이 일치: foaf:knows를 통해 Alice에서 도달할 수 있는 모든 사람의 이름 찾기.

{
  ?x foaf:mbox <mailto:alice@example> .
  ?x foaf:knows+/foaf:name ?name .
}

임의 길이 경로의 대안:

{ ?ancestor (ex:motherOf|ex:fatherOf)+ <#me> }

임의 길이 경로 일치: 일부 형태의 제한된 추론도 가능합니다. 예를 들어 RDFS의 경우, 리소스의 모든 타입과 상위 타입은 다음과 같습니다.

{ <http://example/thing> rdf:type/rdfs:subClassOf* ?type }

모든 리소스와 그 모든 추론된 타입:

{ ?x rdf:type/rdfs:subClassOf* ?type }

하위 속성:

{ ?x ?p ?v . ?p rdfs:subPropertyOf* :property }

부정된 속성 경로: rdf:type으로 연결되지 않은 노드 찾기(어느 방향이든):

{ ?x !(rdf:type|^rdf:type) ?y }

RDF 컬렉션의 요소:

{ :list rdf:rest*/rdf:first ?element }

참고: 이 경로 표현식은 결과의 순서를 보장하지 않습니다.

SPARQL 속성 경로는 RDF 트리플을 이름 있는 간선을 가진 방향성 있고, 순환 가능성이 있는 그래프로 취급합니다. 속성 경로 표현식의 평가는 중복으로 이어질 수 있습니다. 동등한 패턴에서 도입된 변수는 결과의 일부가 아니며 다른 곳에서 이미 사용되지 않기 때문입니다. 이들은 결과를 질의에서 주어진 변수만으로 암시적으로 투영함으로써 숨겨집니다.

예를 들어 다음 데이터에서:

PREFIX :       <http://example/>

:order  :item :z1 .
:order  :item :z2 .

:z1 :name "Small" .
:z1 :price 5 .

:z2 :name "Large" .
:z2 :price 5 .

질의:

PREFIX :   <http://example/>
SELECT * 
{  ?s :item/:price ?x . }

결과:

반면 중간 변수(?_a)를 포함하도록 질의를 풀어 쓰면, 결과의 어떤 행도 중복되지 않습니다.

PREFIX :   <http://example/>
SELECT * 
{  ?s :item ?_a .
   ?_a :price ?x .
}

결과:

그래프 패턴과의 동등성은 질의가 집계 연산도 포함하는 경우 특히 중요합니다. 주문의 총 비용은 다음으로 찾을 수 있습니다.

PREFIX :   <http://example/>
SELECT (sum(?x) AS ?total) { 
    :order :item/:price ?x
}

임의 길이의 속성 경로를 통한 주어와 객체 사이의 연결성은 "zero or more" 속성 경로 연산자 *와 "one or more" 속성 경로 연산자 +를 사용하여 찾을 수 있습니다. 또한 "zero or one" 연결성 속성 경로 연산자 ?도 있습니다.

이들 각 연산자는 연산자가 제한하는 횟수만큼 경로 단계를 사용하여 주어와 객체 사이의 연결을 찾기 위해 속성 경로 표현식을 사용합니다.

예를 들어 리소스의 가능한 모든 타입을, 리소스의 상위 타입을 포함하여 찾는 것은 다음으로 달성할 수 있습니다.

PREFIX  rdfs:   <http://www.w3.org/2000/01/rdf-schema#> . 
PREFIX  rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
SELECT ?x ?type
{ 
    ?x rdf:type/rdfs:subClassOf* ?type
}

마찬가지로, foaf:knows 관계를 통해 :x가 연결되는 모든 사람을 찾는 것은 다음과 같습니다.

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX :     <http://example/>
SELECT ?person
{ 
    :x foaf:knows+ ?person
}

이러한 연결성 일치는 중복을 도입하지 않습니다(연결이 이루어질 수 있는 방식의 수를 포함하지 않습니다). 반복된 경로 자체가 그렇지 않으면 중복을 초래할 수 있더라도 마찬가지입니다.

일치되는 그래프에는 순환이 포함될 수 있습니다. 연결성 일치는 순환을 일치시켜도 정의되지 않거나 무한한 결과로 이어지지 않도록 정의됩니다.

BIND 형식은 기본 그래프 패턴 또는 속성 경로 표현식에서 값을 변수에 할당할 수 있게 합니다. BIND를 사용하면 앞선 기본 그래프 패턴이 종료됩니다. BIND 절이 도입하는 변수는 BIND에서 사용되는 지점까지 그룹 그래프 패턴 안에서 사용된 적이 없어야 합니다.

예제:

PREFIX dc:   <http://purl.org/dc/elements/1.1/>
PREFIX :     <http://example.org/book/>
PREFIX ns:   <http://example.org/ns#>

:book1  dc:title     "SPARQL Tutorial" .
:book1  ns:price     42 .
:book1  ns:discount  0.2 .

:book2  dc:title     "The Semantic Web" .
:book2  ns:price     23 .
:book2  ns:discount  0.25 .

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
PREFIX  ns:  <http://example.org/ns#>

SELECT  ?title ?price
{   
    ?x ns:price ?p .
    ?x ns:discount ?discount
    BIND (?p*(1-?discount) AS ?price)
    FILTER(?price < 20)
    ?x dc:title ?title . 
}

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
PREFIX  ns:  <http://example.org/ns#>

SELECT  ?title ?price
{  { ?x ns:price ?p .
     ?x ns:discount ?discount
     BIND (?p*(1-?discount) AS ?price)
    }
    {?x dc:title ?title . }
    FILTER(?price < 20)
}

데이터는 그래프 패턴 안에 직접 작성하거나 VALUES를 사용하여 질의에 추가할 수 있습니다. VALUES는 해 시퀀스로서 인라인 데이터를 제공하며, 이는 조인 연산을 통해 질의 평가 결과와 결합됩니다. 이는 애플리케이션이 질의 결과에 대한 특정 요구사항을 제공하는 데 사용할 수 있으며, SERVICE 키워드를 통해 연합 질의를 제공하는 SPARQL 질의 엔진 구현이 원격 질의 서비스에 더 제약된 질의를 보내는 데도 사용할 수 있습니다.

VALUES (?x ?y) {
    (:uri1 1)
    (:uri2 UNDEF)
}

VALUES ?z { "abc" "def" }

VALUES (?z) { ("abc") ("def") }

PREFIX dc:   <http://purl.org/dc/elements/1.1/>
PREFIX :     <http://example.org/book/>
PREFIX ns:   <http://example.org/ns#>

:book1  dc:title  "SPARQL Tutorial" .
:book1  ns:price  42 .
:book2  dc:title  "The Semantic Web" .
:book2  ns:price  23 .

PREFIX dc:   <http://purl.org/dc/elements/1.1/> 
PREFIX :     <http://example.org/book/> 
PREFIX ns:   <http://example.org/ns#> 

SELECT ?book ?title ?price
{
    VALUES ?book { :book1 :book3 }
    ?book dc:title ?title ;
          ns:price ?price .
}

PREFIX dc:   <http://purl.org/dc/elements/1.1/> 
PREFIX :     <http://example.org/book/> 
PREFIX ns:   <http://example.org/ns#> 

SELECT ?book ?title ?price
{
    ?book dc:title ?title ;
          ns:price ?price .
    VALUES (?book ?title) {
        (UNDEF "SPARQL Tutorial")
        (:book2 UNDEF)
    }
}

PREFIX dc:   <http://purl.org/dc/elements/1.1/> 
PREFIX :     <http://example.org/book/> 
PREFIX ns:   <http://example.org/ns#> 

SELECT ?book ?title ?price {
    ?book dc:title ?title ;
          ns:price ?price .
}
VALUES (?book ?title) {
    (UNDEF "SPARQL Tutorial")
    (:book2 UNDEF)
}

PREFIX : <http://books.example/>

:org1 :affiliates :auth1, :auth2 .
:auth1 :writesBook :book1, :book2 .
:book1 :price 9 .
:book2 :price 5 .
:auth2 :writesBook :book3 .
:book3 :price 7 .
:org2 :affiliates :auth3 .
:auth3 :writesBook :book4 .
:book4 :price 7 .

PREFIX : <http://books.example/>
SELECT (SUM(?lprice) AS ?totalPrice)
WHERE {
    ?org :affiliates ?auth .
    ?auth :writesBook ?book .
    ?book :price ?lprice .
}
GROUP BY ?org
HAVING (SUM(?lprice) > 10)

이 예제는 집계의 두 가지 기능을 보여 줍니다. GROUP BY는 하나 이상의 표현식(이 경우 ?org)에 따라 질의 해를 그룹화하며, HAVING은 FILTER 표현식과 유사하지만 개별 해가 아니라 그룹에 대해 작동합니다.

이 예제는 GROUP BY 표현식에 따라 해를 그룹화하여 만들어집니다 (즉, ?org가 특정 값을 갖는 모든 해는 같은 그룹 안에 나타남). 그리고 해당 그룹에 대해 집합 함수 SUM을 평가합니다. 그런 다음 그룹은 HAVING 표현식으로 필터링되며, 이는 SUM(?lprice)가 10보다 크지 않은 모든 그룹을 제거합니다.

집계 질의와 하위 질의에서, 질의 패턴에 나타나지만 GROUP BY 절에는 없는 변수는 집계된 경우에만 투영하거나 select 표현식에서 사용할 수 있습니다. SAMPLE 집계는 이 목적에 사용할 수 있습니다. 자세한 내용은 투영 제한 절을 참조하십시오.

함수의 경우와 마찬가지로, 집계 표현식은 질의나 하위 질의에서 투영되기 위해 별칭을 가져야 한다는 점에 유의해야 합니다 (다시 말해 BIND 절과 비슷하게 AS 키워드를 사용합니다). 위 예제에서는 변수 ?totalPrice를 사용하여 이를 수행합니다. 집계가 다른 집계 투영이나 WHERE 절에서 이미 사용된 이름을 가진 변수로 투영되는 것은 오류입니다.

해에 대한 집계 값을 계산하려면, 먼저 해를 하나 이상의 그룹으로 나누고 각 그룹에 대해 집계 값을 계산합니다.

SELECT, HAVING 또는 ORDER BY의 질의 수준에서 집계가 사용되지만 GROUP BY 항이 사용되지 않으면, 이는 모든 해가 속하는 하나의 암시적 그룹으로 간주됩니다.

GROUP BY 절 안에서는 GROUP BY (?x + ?y AS ?z)와 같이 바인딩 키워드 AS를 사용할 수 있습니다. 이는 { ... BIND (?x + ?y AS ?z) } GROUP BY ?z와 동등합니다.

예를 들어 해 시퀀스 S, ( {?x→2, ?y→3}, {?x→2, ?y→5}, {?x→6, ?y→7} )가 주어졌을 때, 해를 ?x 값에 따라 그룹화하고 각 그룹에 대해 ?y 값의 평균을 계산하고자 할 수 있습니다.

이는 다음과 같이 작성할 수 있습니다.

SELECT (AVG(?y) AS ?avg)
WHERE {
    ?a :x ?x ;
    :y ?y .
}
GROUP BY ?x

HAVING은 FILTER가 그룹화되지 않은 해 집합에 대해 작동하는 것과 같은 방식으로, 그룹화된 해 집합에 대해 작동합니다.

HAVING 표현식은 다음 절에 설명된 것처럼 그룹화된 질의의 투영과 동일한 평가 규칙을 가집니다.

HAVING 사용 예는 아래에 제시되어 있습니다.

PREFIX : <http://data.example/>
SELECT (AVG(?size) AS ?asize)
WHERE {
    ?x :size ?size
}
GROUP BY ?x
HAVING(AVG(?size) > 10)

이는 주어별로 그룹화된 평균 크기를 반환하지만, 평균 크기가 10보다 큰 경우에만 반환합니다.

그룹화를 사용하는 질의 수준(명시적인 GROUP BY 절의 사용 또는 투영, HAVING, ORDER BY 절에서 집계를 사용하는 경우)에서, 해당 질의 수준의 투영 또는 SELECT 표현식에 나타나는 변수의 모든 출현은 다음 조건 중 하나를 반드시 만족해야 합니다.

• 변수 V가 이름 있는 GROUP BY 변수로 나타납니다(대응하는 GROUP BY 표현식이 단지 변수 V로 구성되거나, (expr AS V) 형식을 가짐)
• 변수가 SELECT 표현식 안의 하위 표현식의 일부로 나타나며, 이 하위 표현식이 집계의 인자로 사용됩니다(예: MIN(?v) 또는 AVG(?v+2))
• 변수가 같은 SELECT 절의 앞선 SELECT 표현식에 의해 도입됩니다

이러한 변수 출현이 이 조건 중 하나를 만족하지 않으면, 질의는 구문적으로 유효하지 않습니다.

예를 들어 다음 질의는 ?x가 GROUP BY 항으로 주어졌으므로 합법적입니다.

PREFIX : <http://example.com/data/#>
SELECT ?x (MIN(?y) * 2 AS ?min)
WHERE {
    ?x :p ?y .
    ?x :q ?z .
} GROUP BY ?x (STR(?z))

STR(?z)를 투영하는 것은 합법적이지 않다는 점에 유의하십시오. 이 표현식은 단순 변수도 아니고, 이름 있는 GROUP BY 표현식도 아니기 때문입니다. 그러나 GROUP BY ?x (STR(?z) AS ?strZ)를 사용하면 ?strZ를 투영할 수 있습니다.

위 조건을 만족하지 않는 변수를 사용하는 다른 표현식은 SAMPLE 집계를 사용하여 해당 그룹에서 투영할 수 있습니다.

이 절은 집계를 사용하는 예제 질의를 보여 주며, 집계가 있는 경우 결과에서 오류가 어떻게 처리되는지를 보여 줍니다.

데이터:

PREFIX : <http://example.com/data/#>

:x :p 1, 2, 3, 4 .
:y :p 1, _:b2, 3, 4 .
:z :p 1.0, 2.0, 3.0, 4 .

질의:

PREFIX : <http://example.com/data/#>
SELECT ?g (AVG(?p) AS ?avg) ((MIN(?p) + MAX(?p)) / 2 AS ?c)
WHERE {
    ?g :p ?p .
}
GROUP BY ?g

결과:

:y 그룹의 바인딩은 결과에 포함되지 않는다는 점에 유의하십시오. Avg({1, _:b2, 3, 4})의 평가와 (_:b2 + 4) / 2가 오류이므로, 해에서 바인딩이 제거되기 때문입니다.

데이터:

PREFIX : <http://people.example/>

:alice :name "Alice", "Alice Foo", "A. Foo" .
:alice :knows :bob, :carol .
:bob :name "Bob", "Bob Bar", "B. Bar" .
:carol :name "Carol", "Carol Baz", "C. Baz" .

PREFIX : <http://people.example/>
PREFIX : <http://people.example/>

SELECT ?y ?minName
WHERE {
    :alice :knows ?y .
    {
      SELECT ?y (MIN(?name) AS ?minName)
      WHERE {
          ?y :name ?name .
      } GROUP BY ?y
    }
}

결과:

이 결과는 먼저 내부 질의를 평가하여 얻어집니다.

SELECT ?y (MIN(?name) AS ?minName)
WHERE {
    ?y :name ?name .
} GROUP BY ?y

이는 다음 해 시퀀스를 생성합니다.

이는 외부 질의의 결과와 조인됩니다.

RDF 데이터셋의 정의 [RDF12-CONCEPTS]는 명명된 그래프와 기본 그래프의 관계를 제한하지 않습니다. 정보는 서로 다른 그래프에서 반복될 수 있으며, 그래프 사이의 관계가 노출될 수 있습니다. 유용한 두 가지 배치는 다음과 같습니다.

• 명명된 그래프에 대한 출처 정보를 포함하는 정보를 기본 그래프에 두는 것
• 명명된 그래프의 정보를 기본 그래프에도 포함하는 것.

PREFIX dc: <http://purl.org/dc/elements/1.1/>

<http://example.org/bob>    dc:publisher  "Bob" .
<http://example.org/alice>  dc:publisher  "Alice" .

GRAPH <http://example.org/bob> {
    _:a foaf:name "Bob" .
    _:a foaf:mbox <mailto:bob@oldcorp.example.org> .
}

GRAPH <http://example.org/alice> {
    _:a foaf:name "Alice" .
    _:a foaf:mbox <mailto:alice@work.example.org> .
}

이 예제에서 기본 그래프는 두 명명된 그래프의 게시자 이름을 포함합니다. 이 예제에서 명명된 그래프의 트리플은 기본 그래프에 보이지 않습니다.

예제 2:

RDF 데이터는 그래프의 RDF 병합 [RDF12-SEMANTICS]으로 결합할 수 있습니다. RDF 데이터셋 안에서 가능한 그래프 배치 중 하나는 기본 그래프를 명명된 그래프의 정보 일부 또는 전부에 대한 RDF 병합으로 두는 것입니다.

다음 예제에서 명명된 그래프는 이전과 같은 트리플을 포함합니다. RDF 데이터셋은 빈 노드를 구별해 유지하는 명명된 그래프의 RDF 병합을 기본 그래프에 포함합니다.

PREFIX foaf: <http://xmlns.com/foaf/0.1/>

_:x foaf:name "Bob" .
_:x foaf:mbox <mailto:bob@oldcorp.example.org> .

_:y foaf:name "Alice" .
_:y foaf:mbox <mailto:alice@work.example.org> .

GRAPH <http://example.org/bob> {
    _:a foaf:name "Bob" .
    _:a foaf:mbox <mailto:bob@oldcorp.example.org> .
}

GRAPH <http://example.org/alice> {
    _:a foaf:name "Alice" .
    _:a foaf:mbox <mailto:alice@work.example> .
}

SPARQL 질의는 RDF 데이터셋을 설명하기 위해 FROM 절과 FROM NAMED 절을 사용하여 일치에 사용할 데이터셋을 지정할 수 있습니다. 질의가 이러한 데이터셋 설명을 제공하면, 질의에 데이터셋 설명이 제공되지 않았을 때 질의 서비스가 사용할 데이터셋 대신 사용됩니다. RDF 데이터셋은 SPARQL 프로토콜 요청에서 지정될 수도 있으며, 이 경우 프로토콜 설명은 질의 자체의 설명을 재정의합니다. 데이터셋 설명이 서비스에 허용되지 않는 경우 질의 서비스는 질의 요청을 거부할 수 있습니다.

FROM 및 FROM NAMED 키워드는 질의가 참조로 RDF 데이터셋을 지정할 수 있게 합니다. 이들은 데이터셋이 주어진 IRI(즉, 주어진 IRI 참조의 절대 형식)로 식별되는 리소스의 표현에서 얻어진 그래프를 포함해야 함을 나타냅니다. 여러 FROM 및 FROM NAMED 절에서 생기는 데이터셋은 다음과 같습니다.

• FROM 절에서 참조된 그래프의 RDF 병합으로 구성된 기본 그래프, 그리고
• 각 FROM NAMED 절에서 하나씩 오는 (IRI, 그래프) 쌍의 집합.

FROM 절이 없지만 하나 이상의 FROM NAMED 절이 있는 경우, 데이터셋은 기본 그래프로 빈 그래프를 포함합니다.

# Default graph (located at http://example.org/foaf/aliceFoaf)
PREFIX  foaf:  <http://xmlns.com/foaf/0.1/>

_:a  foaf:name     "Alice" .
_:a  foaf:mbox     <mailto:alice@work.example> .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT  ?name
FROM    <http://example.org/foaf/aliceFoaf>
WHERE   { ?x foaf:name ?name }

# Graph: http://example.org/bob
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

_:a foaf:name "Bob" .
_:a foaf:mbox <mailto:bob@oldcorp.example.org> .

# Graph: http://example.org/alice
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

_:a foaf:name "Alice" .
_:a foaf:mbox <mailto:alice@work.example> .

...
FROM NAMED <http://example.org/alice>
FROM NAMED <http://example.org/bob>
...

# Default graph (located at http://example.org/dft.ttl)
PREFIX dc: <http://purl.org/dc/elements/1.1/>

<http://example.org/bob>    dc:publisher  "Bob Hacker" .
<http://example.org/alice>  dc:publisher  "Alice Hacker" .

# Named graph: http://example.org/bob
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

_:a foaf:name "Bob" .
_:a foaf:mbox <mailto:bob@oldcorp.example.org> .

# Named graph: http://example.org/alice
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

_:a foaf:name "Alice" .
_:a foaf:mbox <mailto:alice@work.example.org> .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>

SELECT ?who ?g ?mbox
FROM <http://example.org/dft.ttl>
FROM NAMED <http://example.org/alice>
FROM NAMED <http://example.org/bob>
WHERE
{
    ?g dc:publisher ?who .
    GRAPH ?g { ?x foaf:mbox ?mbox }
}

그래프 컬렉션을 질의할 때, GRAPH 키워드는 명명된 그래프에 대해 패턴을 일치시키는 데 사용됩니다. GRAPH는 하나의 그래프를 선택하기 위해 IRI를 제공할 수도 있고, 질의의 RDF 데이터셋에 있는 모든 명명된 그래프의 IRI를 범위로 하는 변수를 사용할 수도 있습니다.

GRAPH를 사용하면 질의의 해당 부분 안에서 그래프 패턴을 일치시키는 활성 그래프가 변경됩니다. GRAPH 사용 밖에서는 기본 그래프를 사용하여 일치가 수행됩니다.

다음 두 그래프는 예제에서 사용됩니다.

# Named graph: http://example.org/foaf/aliceFoaf
PREFIX  foaf:     <http://xmlns.com/foaf/0.1/>
PREFIX  rdf:      <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  rdfs:     <http://www.w3.org/2000/01/rdf-schema#>

_:a  foaf:name     "Alice" .
_:a  foaf:mbox     <mailto:alice@work.example> .
_:a  foaf:knows    _:b .

_:b  foaf:name     "Bob" .
_:b  foaf:mbox     <mailto:bob@work.example> .
_:b  foaf:nick     "Bobby" .
_:b  rdfs:seeAlso  <http://example.org/foaf/bobFoaf> .

<http://example.org/foaf/bobFoaf>
rdf:type      foaf:PersonalProfileDocument .

# Named graph: http://example.org/foaf/bobFoaf
PREFIX  foaf:     <http://xmlns.com/foaf/0.1/>
PREFIX  rdf:      <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  rdfs:     <http://www.w3.org/2000/01/rdf-schema#>

_:z  foaf:mbox     <mailto:bob@work.example> .
_:z  rdfs:seeAlso  <http://example.org/foaf/bobFoaf> .
_:z  foaf:nick     "Robert" .

<http://example.org/foaf/bobFoaf>
        rdf:type      foaf:PersonalProfileDocument .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>

SELECT ?src ?bobNick
FROM NAMED <http://example.org/foaf/aliceFoaf>
FROM NAMED <http://example.org/foaf/bobFoaf>
WHERE
{
    GRAPH ?src
    { ?x foaf:mbox <mailto:bob@work.example> .
      ?x foaf:nick ?bobNick
    }
}

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX data: <http://example.org/foaf/>

SELECT ?nick
FROM NAMED <http://example.org/foaf/aliceFoaf>
FROM NAMED <http://example.org/foaf/bobFoaf>
WHERE
{
    GRAPH data:bobFoaf {
        ?x foaf:mbox <mailto:bob@work.example> .
        ?x foaf:nick ?nick 
    }
}

PREFIX  data:  <http://example.org/foaf/>
PREFIX  foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX  rdfs:  <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?mbox ?nick ?ppd
FROM NAMED <http://example.org/foaf/aliceFoaf>
FROM NAMED <http://example.org/foaf/bobFoaf>
WHERE {
    GRAPH data:aliceFoaf {
        ?alice foaf:mbox <mailto:alice@work.example> ;
               foaf:knows ?whom .
        ?whom  foaf:mbox ?mbox ;
               rdfs:seeAlso ?ppd .
        ?ppd  a foaf:PersonalProfileDocument .
    }
    GRAPH ?ppd {
        ?w foaf:mbox ?mbox ;
           foaf:nick ?nick
    }
}

Alice의 FOAF 파일에서 Bob의 nick을 제공하는 어떤 트리플도 Bob의 nick을 제공하는 데 사용되지 않습니다. 변수 nick을 포함하는 패턴이 ppd에 의해 특정 개인 프로필 문서로 제한되기 때문입니다.

# Default graph
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX g:  <tag:example.org,2005-06-06:>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

g:graph1 dc:publisher "Bob" .
g:graph1 dc:date "2004-12-06"^^xsd:date .

g:graph2 dc:publisher "Bob" .
g:graph2 dc:date "2005-01-10"^^xsd:date .

# Graph: locally allocated IRI: tag:example.org,2005-06-06:graph1
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

_:a foaf:name "Alice" .
_:a foaf:mbox <mailto:alice@work.example> .

_:b foaf:name "Bob" .
_:b foaf:mbox <mailto:bob@oldcorp.example.org> .

# Graph: locally allocated IRI: tag:example.org,2005-06-06:graph2
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

_:a foaf:name "Alice" .
_:a foaf:mbox <mailto:alice@work.example> .

_:b foaf:name "Bob" .
_:b foaf:mbox <mailto:bob@newcorp.example.org> .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dc:   <http://purl.org/dc/elements/1.1/>

SELECT ?name ?mbox ?date
WHERE {
   ?g dc:publisher ?name ;
      dc:date ?date .
   GRAPH ?g { 
       ?person foaf:name ?name ; foaf:mbox ?mbox
   }
}

ORDER BY 절은 해 시퀀스의 순서를 설정합니다.

ORDER BY 절 뒤에는 표현식과 선택적 정렬 수정자(ASC() 또는 DESC())로 구성된 정렬 비교자의 시퀀스가 옵니다. 각 정렬 비교자는 오름차순(ASC() 수정자로 표시되거나 수정자가 없음) 또는 내림차순(DESC() 수정자로 표시됨)입니다.

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>

SELECT ?name
WHERE { ?x foaf:name ?name }
ORDER BY ?name

PREFIX     :    <http://example.org/ns#>
PREFIX foaf:    <http://xmlns.com/foaf/0.1/>

SELECT ?name
WHERE { ?x foaf:name ?name ; :empId ?emp }
ORDER BY DESC(?emp)

PREFIX     :    <http://example.org/ns#>
PREFIX foaf:    <http://xmlns.com/foaf/0.1/>

SELECT ?name
WHERE { ?x foaf:name ?name ; :empId ?emp }
ORDER BY ?name DESC(?emp)

"<" 연산자(연산자 매핑 및 연산자 확장성 참조)는 numerics, xsd:strings, xsd:booleans 및 xsd:dateTimes 쌍의 상대적 순서를 정의합니다. IRI 쌍은 데이터 타입이 xsd:string인 리터럴로 비교하여 정렬됩니다.

SPARQL은 그렇지 않으면 정렬되지 않을 일부 종류의 RDF 용어 사이의 순서도 고정합니다.

1. (가장 낮음) 이 해에서 변수 또는 표현식에 할당된 값이 없음.
2. 빈 노드
3. IRI
4. RDF 리터럴
5. 트리플 용어

SPARQL은 가능한 모든 RDF 용어의 전체 순서를 정의하지 않습니다. 구현은 연산자 확장성을 통해 전체 순서를 정의할 수 있습니다. 다음은 상대적 순서가 정의되지 않은 용어 쌍의 몇 가지 예입니다.

• "a"와 "a"@en_gb(데이터 타입이 xsd:string인 리터럴과 언어 태그가 있는 리터럴)
• "a"@en_gb와 "b"@en_gb(언어 태그가 있는 두 리터럴)
• "a"와 "1"^^xsd:integer(데이터 타입이 xsd:string인 리터럴과 지원되는 데이터 타입을 가진 리터럴)
• "1"^^my:integer와 "2"^^my:integer(지원되지 않는 두 데이터 타입)
• "1"^^xsd:integer와 "2"^^my:integer(지원되는 데이터 타입과 지원되지 않는 데이터 타입)
• << :person1 foaf:name "Bob" >> 및 << :person2 foaf:name "Alice" >>(두 트리플 용어)

이 변수 바인딩 목록은 오름차순입니다.

정렬 비교자에 대한 두 해의 오름차순은 해 바인딩을 표현식에 대입하고 "<" 연산자로 비교하여 설정됩니다. 내림차순은 오름차순의 반대입니다.

두 해의 상대적 순서는 시퀀스의 첫 번째 정렬 비교자에 대한 두 해의 상대적 순서입니다. 해 바인딩의 대입이 같은 RDF 용어를 생성하는 해의 경우, 순서는 다음 정렬 비교자에 대한 두 해의 상대적 순서입니다. 두 해에 대해 평가된 어떤 정렬 표현식도 서로 다른 RDF 용어를 생성하지 않으면 두 해의 상대적 순서는 정의되지 않습니다.

해 시퀀스를 정렬하면 항상 같은 수의 해를 포함하는 시퀀스가 됩니다.

CONSTRUCT 또는 DESCRIBE 질의에 대한 해 시퀀스에서 ORDER BY를 사용하는 것은 직접적인 효과가 없습니다. 오직 SELECT만 결과 시퀀스를 반환하기 때문입니다. LIMIT 및 OFFSET과 함께 사용하면, ORDER BY는 해 시퀀스의 다른 슬라이스에서 생성된 결과를 반환하는 데 사용할 수 있습니다. ASK 질의는 ORDER BY, LIMIT 또는 OFFSET을 포함하지 않습니다.

해 시퀀스는 변수의 부분집합만 포함하는 시퀀스로 변환될 수 있습니다. 시퀀스의 각 해에 대해 SELECT 질의 형식을 사용하여 지정된 변수 선택으로 새 해가 형성됩니다.

다음 예제는 FOAF 속성을 사용하여 RDF 그래프에 설명된 사람들의 이름만 추출하는 질의를 보여 줍니다.

PREFIX foaf:        <http://xmlns.com/foaf/0.1/>

_:a  foaf:name       "Alice" .
_:a  foaf:mbox       <mailto:alice@work.example> .

_:b  foaf:name       "Bob" .
_:b  foaf:mbox       <mailto:bob@work.example> .

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>
SELECT ?name
WHERE
{ ?x foaf:name ?name }

DISTINCT 또는 REDUCED 질의 수정자가 없는 해 시퀀스는 중복 해를 보존합니다.

PREFIX  foaf:  <http://xmlns.com/foaf/0.1/>

_:x    foaf:name   "Alice" .
_:x    foaf:mbox   <mailto:alice@example.com> .

_:y    foaf:name   "Alice" .
_:y    foaf:mbox   <mailto:asmith@example.com> .

_:z    foaf:name   "Alice" .
_:z    foaf:mbox   <mailto:alice.smith@example.com> .

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
SELECT ?name WHERE { ?x foaf:name ?name }

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
SELECT DISTINCT ?name WHERE { ?x foaf:name ?name }

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
SELECT REDUCED ?name WHERE { ?x foaf:name ?name }

OFFSET은 생성된 해가 지정된 수의 해 이후부터 시작되게 합니다. OFFSET이 0이면 아무 효과가 없습니다.

LIMIT과 OFFSET을 사용하여 질의 해의 서로 다른 부분집합을 선택하는 것은 ORDER BY를 사용하여 순서를 예측 가능하게 만들지 않는 한 유용하지 않습니다.

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>

SELECT  ?name
WHERE   { ?x foaf:name ?name }
ORDER BY ?name
LIMIT   5
OFFSET  10

LIMIT 절은 반환되는 해의 수에 상한을 둡니다. OFFSET이 적용된 후 실제 해의 수가 limit보다 크면, 최대 limit 수만큼의 해만 반환됩니다.

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>

SELECT ?name
WHERE { ?x foaf:name ?name }
LIMIT 20

LIMIT이 0이면 결과가 반환되지 않습니다. limit는 음수일 수 없습니다.

SELECT 결과 형식은 변수와 그 바인딩을 직접 반환합니다. 이는 필요한 변수를 투영하는 작업과 새 변수 바인딩을 질의 해에 도입하는 작업을 결합합니다.

PREFIX  foaf:  <http://xmlns.com/foaf/0.1/>

_:a    foaf:name   "Alice" .
_:a    foaf:knows  _:b .
_:a    foaf:knows  _:c .

_:b    foaf:name   "Bob" .

_:c    foaf:name   "Clare" .
_:c    foaf:nick   "CT" .

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
SELECT ?nameX ?nameY ?nickY
WHERE
{ ?x foaf:knows ?y ;
  foaf:name ?nameX .
  ?y foaf:name ?nameY .
  OPTIONAL { ?y foaf:nick ?nickY }
}

{
    "head": {
        "vars": [ "nameX" , "nameY" , "nickY" ]
    } ,
    "results": {
        "bindings": [
          {
            "nameX": { "type": "literal" , "value": "Alice" } ,
            "nameY": { "type": "literal" , "value": "Bob" }
          } ,
          {
            "nameX": { "type": "literal" , "value": "Alice" } ,
            "nameY": { "type": "literal" , "value": "Clare" } ,
            "nickY": { "type": "literal" , "value": "CT" }
          }
        ]
    }
}

<?xml version="1.0"?>
<sparql xmlns="http://www.w3.org/2005/sparql-results#">
<head>
<variable name="nameX"/>
<variable name="nameY"/>
<variable name="nickY"/>
</head>
<results>
<result>
<binding name="nameX">
<literal>Alice</literal>
</binding>
<binding name="nameY">
<literal>Bob</literal>
</binding>
</result>
<result>
<binding name="nameX">
<literal>Alice</literal>
</binding>
<binding name="nameY">
<literal>Clare</literal>
</binding>
<binding name="nickY">
<literal>CT</literal>
</binding>
</result>
</results>
</sparql>

PREFIX dc:   <http://purl.org/dc/elements/1.1/>
PREFIX :     <http://example.org/book/>
PREFIX ns:   <http://example.org/ns#>

:book1  dc:title  "SPARQL Tutorial" .
:book1  ns:price  42 .
:book1  ns:discount 0.2 .

:book2  dc:title  "The Semantic Web" .
:book2  ns:price  23 .
:book2  ns:discount 0.25 .

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
PREFIX  ns:  <http://example.org/ns#>
SELECT  ?title (?p*(1-?discount) AS ?price)
{ ?x ns:price ?p .
  ?x dc:title ?title . 
  ?x ns:discount ?discount 
}

PREFIX  dc:  <http://purl.org/dc/elements/1.1/>
PREFIX  ns:  <http://example.org/ns#>
SELECT  ?title (?p AS ?fullPrice) (?fullPrice*(1-?discount) AS ?customerPrice)
{ ?x ns:price ?p .
  ?x dc:title ?title . 
  ?x ns:discount ?discount 
}

CONSTRUCT 질의 형식은 그래프 템플릿으로 지정된 단일 RDF 그래프를 반환합니다. 결과는 해 시퀀스의 각 질의 해를 가져와 그래프 템플릿의 변수에 대입하고, 트리플을 집합 합집합으로 결합하여 형성된 RDF 그래프입니다.

이러한 인스턴스화가 바인딩되지 않은 변수를 포함하는 트리플이나 주어 또는 술어 위치의 리터럴과 같은 잘못된 RDF 구성을 생성하면, 해당 트리플은 출력 RDF 그래프에 포함되지 않습니다. 그래프 템플릿은 변수가 없는 트리플(ground 또는 explicit 트리플로 알려짐)을 포함할 수 있으며, 이들도 CONSTRUCT 질의 형식이 반환하는 출력 RDF 그래프에 나타납니다.

PREFIX  foaf:  <http://xmlns.com/foaf/0.1/>

_:a    foaf:name   "Alice" .
_:a    foaf:mbox   <mailto:alice@example.org> .

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
PREFIX vcard:   <http://www.w3.org/2001/vcard-rdf/3.0#>
CONSTRUCT   { <http://example.org/person#Alice> vcard:FN ?name }
WHERE       { ?x foaf:name ?name }

PREFIX vcard: <http://www.w3.org/2001/vcard-rdf/3.0#>

<http://example.org/person#Alice> vcard:FN "Alice" .

PREFIX  foaf:  <http://xmlns.com/foaf/0.1/>

_:a    foaf:givenname   "Alice" .
_:a    foaf:family_name "Hacker" .

_:b    foaf:firstname   "Bob" .
_:b    foaf:surname     "Hacker" .

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
PREFIX vcard:   <http://www.w3.org/2001/vcard-rdf/3.0#>

CONSTRUCT {
     ?x  vcard:N _:v .
    _:v vcard:givenName ?gname .
    _:v vcard:familyName ?fname
} WHERE {
    { ?x foaf:firstname ?gname } UNION  { ?x foaf:givenname   ?gname } .
    { ?x foaf:surname   ?fname } UNION  { ?x foaf:family_name ?fname } .
}

PREFIX vcard: <http://www.w3.org/2001/vcard-rdf/3.0#>

_:a vcard:N         _:v1 .
_:v1 vcard:givenName  "Alice" .
_:v1 vcard:familyName "Hacker" .

_:b vcard:N         _:v2 .
_:v2 vcard:givenName  "Bob" .
_:v2 vcard:familyName "Hacker" .

CONSTRUCT { ?s ?p ?o } WHERE { GRAPH <http://example.org/aGraph> { ?s ?p ?o } . }

PREFIX  dc: <http://purl.org/dc/elements/1.1/>
PREFIX app: <http://example.org/ns#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

CONSTRUCT { ?s ?p ?o } WHERE
{
    GRAPH ?g { ?s ?p ?o } .
    ?g dc:publisher <http://www.w3.org/> .
    ?g dc:date ?date .
    FILTER ( app:customDate(?date) > "2005-02-28T00:00:00Z"^^xsd:dateTime ) .
}

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX site: <http://example.org/stats#>

_:a foaf:name "Alice" .
_:a site:hits 2349 .

_:b foaf:name "Bob" .
_:b site:hits 105 .

_:c foaf:name "Eve" .
_:c site:hits 181 .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX site: <http://example.org/stats#>

CONSTRUCT { [] foaf:name ?name }
WHERE
{ [] foaf:name ?name ;
  site:hits ?hits .
}
ORDER BY desc(?hits)
LIMIT 2

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
_:x foaf:name "Alice" .
_:y foaf:name "Eve" .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
CONSTRUCT WHERE { ?x foaf:name ?name }

PREFIX foaf: <http://xmlns.com/foaf/0.1/>

CONSTRUCT { ?x foaf:name ?name } 
WHERE
{ ?x foaf:name ?name }

애플리케이션은 질의 패턴에 해가 있는지 여부를 테스트하기 위해 ASK 형식을 사용할 수 있습니다. 가능한 질의 해에 대한 정보는 반환되지 않고, 단지 해가 존재하는지 여부만 반환됩니다.

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>

_:a  foaf:name       "Alice" .
_:a  foaf:homepage   <http://work.example.org/alice/> .

_:b  foaf:name       "Bob" .
_:b  foaf:mbox       <mailto:bob@work.example> .

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
ASK  { ?x foaf:name  "Alice" }

true

<?xml version="1.0"?>
                <sparql xmlns="http://www.w3.org/2005/sparql-results#">
                <head></head>
                <boolean>true</boolean>
                </sparql>

PREFIX foaf:    <http://xmlns.com/foaf/0.1/>
ASK  {
   ?x foaf:name  "Alice" ;
      foaf:mbox  <mailto:alice@work.example>
}

false

DESCRIBE 형식은 리소스에 대한 RDF 데이터를 포함하는 단일 결과 RDF 그래프를 반환합니다. 이 데이터는 SPARQL 질의가 규정하는 것이 아니며, 그런 경우 질의 클라이언트는 데이터 소스에 있는 RDF의 구조를 알아야 합니다. 대신 이는 SPARQL 질의 처리기에 의해 결정됩니다. 질의 패턴은 결과 집합을 만드는 데 사용됩니다. DESCRIBE 형식은 해에서 식별된 각 리소스와 IRI로 직접 이름 붙은 모든 리소스를 가져와, 대상 RDF 데이터셋을 포함해 이용 가능한 어떤 정보에서도 나올 수 있는 "설명"을 취함으로써 단일 RDF 그래프를 조립합니다. 설명은 질의 서비스에 의해 결정됩니다. 구문 DESCRIBE *는 질의의 모든 변수를 설명하는 축약입니다.

DESCRIBE <http://example.org/>

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
DESCRIBE ?x
WHERE    { ?x foaf:mbox <mailto:alice@org> }

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
DESCRIBE ?x
WHERE    { ?x foaf:name "Alice" }

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
DESCRIBE ?x ?y <http://example.org/>
WHERE    {?x foaf:knows ?y}

PREFIX ent:  <http://org.example.com/employees#>
DESCRIBE ?x WHERE { ?x ent:employeeId "1234" }

PREFIX foaf:   <http://xmlns.com/foaf/0.1/>
PREFIX vcard:  <http://www.w3.org/2001/vcard-rdf/3.0>
PREFIX exOrg:  <http://org.example.com/employees#>
PREFIX rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl:    <http://www.w3.org/2002/07/owl#>

_:a     exOrg:employeeId    "1234" ;
        foaf:mbox_sha1sum   "bee135d3af1e418104bc42904596fe148e90f033" ;
        vcard:N
          [ vcard:Family       "Smith" ;
            vcard:Given        "John"  ] .
foaf:mbox_sha1sum  rdf:type  owl:InverseFunctionalProperty .

SPARQL 함수와 연산자는 RDF 용어와 SPARQL 변수에 대해 작동합니다. 이러한 함수와 연산자의 일부는 XPath and XQuery Functions and Operators 3.1 [XPATH-FUNCTIONS-31]에서 가져온 것이며, XML Schema 타입이 지정된 값 인자와 반환 타입을 가집니다. 이러한 함수와 연산자에 인자로 전달된 RDF literals는 lexical form의 문자열 값과 데이터 타입 IRI에 대응하는 원자 데이터 타입을 가진 XML Schema 타입 값으로 매핑됩니다. 반환된 타입 값은 같은 방식으로 RDF literals로 다시 매핑됩니다.

SPARQL에는 RDF 용어의 특정 부분집합에 대해 작동하는 추가 연산자가 있습니다. 타입을 언급할 때, 다음 용어들은 대응하는 W3C XML Schema Definition Language (XSD) 1.1 Part 2: Datatypes [XMLSCHEMA11-2] 데이터 타입 IRI를 가진 literal을 나타냅니다.

• xsd:integer
• xsd:decimal
• xsd:float
• xsd:double
• xsd:string
• xsd:boolean
• xsd:dateTime

다음 용어들은 SPARQL 값 테스트에서 사용되는 추가 타입을 식별합니다.

• numeric은 xsd:integer, xsd:decimal, xsd:float 또는 xsd:double 데이터 타입을 가진 리터럴을 나타냅니다.
• RDF term은 IRI, 리터럴, 빈 노드 또는 트리플 용어 타입을 나타냅니다.
• variable은 SPARQL 변수를 나타냅니다.

다음 타입들은 numeric 타입에서 파생되며, numeric 인자를 받는 함수와 연산자에 대한 유효한 인자입니다.

• xsd:nonPositiveInteger
• xsd:negativeInteger
• xsd:long
• xsd:int
• xsd:short
• xsd:byte
• xsd:nonNegativeInteger
• xsd:unsignedLong
• xsd:unsignedInt
• xsd:unsignedShort
• xsd:unsignedByte
• xsd:positiveInteger

SPARQL 언어 확장은 XML schema 데이터 타입에서 파생된 것으로 취급되는 추가 타입을 다룰 수 있습니다.

SPARQL 표현식은 해 매핑과 관련하여, 그리고 활성 그래프를 가진 RDF 데이터셋의 문맥에서 평가됩니다. 이러한 평가의 결과는 RDF 용어 또는 오류입니다.

SPARQL은 XPath and XQuery Functions and Operators가 정의한 함수와 연산자의 부분집합을 제공합니다. 다음 규칙은 XPath/XQuery와 SPARQL 사이의 데이터 및 실행 모델 차이를 수용합니다.

• XPath/XQuery의 함수와 달리, SPARQL의 함수는 노드 시퀀스를 처리하지 않습니다.
• 잘못된 타입의 인자로 호출된 함수는 오류를 생성합니다.
• 유효 불리언 값 인자(아래 연산자 매핑 표에서 "xsd:boolean (EBV)"로 표시됨)는 SPARQL EBV 규칙을 사용하여 xsd:boolean으로 강제 변환됩니다.
• 함수형 형식 BOUND, COALESCE, IF, IN, NOT IN, logical-or (||), logical-and (&&), logical-not (!), NOT EXISTS, EXISTS, 그리고 EBV를 제외하고, 모든 함수는 RDF 용어에 대해 작동합니다. 인자가 바인딩되지 않은 경우 함수는 오류를 생성합니다.
• logical-or (||) 또는 logical-and (&&)를 제외한 모든 표현식은 오류를 만나면 그 오류를 생성합니다.
• logical-or가 한 분기에서만 오류를 만나면, 다른 분기가 TRUE인 경우 TRUE를 반환하고, 다른 분기가 FALSE인 경우 오류를 반환합니다.
• logical-and가 한 분기에서만 오류를 만나면, 다른 분기가 TRUE인 경우 오류를 반환하고, 다른 분기가 FALSE인 경우 FALSE를 반환합니다.
• logical-or 또는 logical-and가 양쪽 분기에서 오류를 만나면, 오류 중 어느 하나를 생성합니다.

true(T), false (F) 및 오류(E)에 대한 logical-and와 logical-or 진리표는 다음과 같습니다.

xsd:boolean  EBV (RDF term term)

SPARQL 문법은 제약을 구성하는 데 사용되는 연산자 집합 (예: &&, *, isIRI)을 식별합니다. 다음 표는 이러한 각 문법 생성식을 적절한 피연산자 및 XPath and XQuery Functions and Operators 3.1 [XPATH-FUNCTIONS-31] 또는 17.4절에 지정된 SPARQL 연산자가 정의한 연산자 함수와 연결합니다. 주어진 매개변수 집합에 대한 연산자 정의를 선택할 때에는 가장 구체적인 매개변수를 가진 정의가 적용됩니다. 예를 들어 xsd:integer = xsd:signedInt를 평가할 때, 두 RDF 용어를 가진 정의가 아니라 두 numeric 매개변수를 가진 = 정의가 적용됩니다. 표는 가장 위쪽의 가능한 후보가 가장 구체적이도록 배치되어 있습니다. 적절한 피연산자 없이 호출된 연산자는 오류를 발생시킵니다.

SPARQL은 숫자 연산자에 대한 인자의 숫자 타입 승격 및 하위 타입 대체에 대해 XPath의 체계를 따릅니다. numeric 피연산자 (xsd:integer, xsd:decimal, xsd:float, xsd:double, 그리고 numeric 타입에서 파생된 타입)에 대한 XPath Operator Mapping 규칙은 SPARQL 연산자에도 적용됩니다(숫자 타입 승격 및 하위 타입 대체의 정의는 XML Path Language (XPath) 3.1 [XPATH-31]를 참조하십시오). 일부 연산자는 중첩된 함수 표현식과 연결됩니다. 예: fn:not(op:numeric-equal(A, B)). XPath 정의에 따라, fn:not와 op:numeric-equal은 인자가 오류인 경우 오류를 생성한다는 점에 유의하십시오.

fn:compare에 대한 정렬은 XPath에서 정의되며 http://www.w3.org/2005/xpath-functions/collation/codepoint로 식별됩니다. 이 정렬은 코드 포인트 값에 기반한 문자열 비교를 허용합니다. 코드 포인트 문자열 동등성은 RDF 용어 동등성으로 테스트할 수 있습니다.

"(EBV)"로 표시된 xsd:boolean 함수 인자는 해당 인자의 유효 불리언 값을 평가하여 xsd:boolean으로 강제 변환됩니다.

트리플 용어에 적용된 연산자 = 및 !=는 각 구성 요소에 연산자를 적용합니다.

本节定义由 SPARQL 查询语言引入的运算符和函数。 示例展示这些运算符在由适当文法结构调用时的行为。

xsd:boolean  BOUND (variable var)

PREFIX foaf:        <http://xmlns.com/foaf/0.1/>
PREFIX dc:          <http://purl.org/dc/elements/1.1/>
PREFIX xsd:          <http://www.w3.org/2001/XMLSchema#>

_:a  foaf:givenName  "Alice".

_:b  foaf:givenName  "Bob" .
_:b  dc:date         "2005-04-04T04:04:04Z"^^xsd:dateTime .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dc:   <http://purl.org/dc/elements/1.1/>
PREFIX xsd:   <http://www.w3.org/2001/XMLSchema#>
SELECT ?givenName
WHERE {
   ?x foaf:givenName  ?givenName .
   OPTIONAL { ?x dc:date ?date } .
   FILTER ( bound(?date) )
}

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dc:   <http://purl.org/dc/elements/1.1/>
SELECT ?name
WHERE { 
    ?x foaf:givenName  ?name .
    OPTIONAL { ?x dc:date ?date } .
    FILTER (!bound(?date))
 }

rdfTerm  IF (expression1, expression2, expression3)

rdfTerm COALESCE(expression, ....)

xsd:boolean  NOT EXISTS { pattern }

xsd:boolean EXISTS { pattern }

xsd:boolean logical-or (xsd:boolean left, xsd:boolean right)

xsd:boolean logical-and (xsd:boolean left, xsd:boolean right)

xsd:boolean logical-not (xsd:boolean arg)

boolean  rdfTerm IN (expression, ...)

(rdfTerm = value of expression1) || (rdfTerm = value of expression2) || ...

boolean  rdfTerm NOT IN (expression, ...)

(rdfTerm != value of expression1) && (rdfTerm != value of expression2) && ...

xsd:boolean  sameTerm (RDF term term1, RDF term term2)

xsd:boolean sameValue (RDF term term1, RDF term term2)

xsd:boolean  isIRI (RDF term term)
xsd:boolean  isURI (RDF term term)

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>

_:a  foaf:name       "Alice".
_:a  foaf:mbox       <mailto:alice@work.example> .

_:b  foaf:name       "Bob" .
_:b  foaf:mbox       "bob@work.example" .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE {
    ?x foaf:name  ?name ;
       foaf:mbox  ?mbox .
    FILTER isIRI(?mbox) 
}

xsd:boolean  isBLANK (RDF term term)

PREFIX a:          <http://www.w3.org/2000/10/annotation-ns#>
PREFIX dc:         <http://purl.org/dc/elements/1.1/>
PREFIX foaf:       <http://xmlns.com/foaf/0.1/>

_:a   a:annotates   <http://www.w3.org/TR/rdf-sparql-query/> .
_:a   dc:creator    "Alice B. Toeclips" .

_:b   a:annotates   <http://www.w3.org/TR/rdf-sparql-query/> .
_:b   dc:creator    _:c .
_:c   foaf:given    "Bob".
_:c   foaf:family   "Smith".

PREFIX a:      <http://www.w3.org/2000/10/annotation-ns#>
PREFIX dc:     <http://purl.org/dc/elements/1.1/>
PREFIX foaf:   <http://xmlns.com/foaf/0.1/>

SELECT ?given ?family
WHERE { 
    ?annot  a:annotates  <http://www.w3.org/TR/rdf-sparql-query/> .
    ?annot  dc:creator   ?c .
    OPTIONAL { ?c  foaf:given   ?given ; foaf:family  ?family } .
    FILTER isBLANK(?c)
}

xsd:boolean  isLITERAL (RDF term term)

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>
                
_:a  foaf:name       "Alice".
_:a  foaf:mbox       <mailto:alice@work.example> .

_:b  foaf:name       "Bob" .
_:b  foaf:mbox       "bob@work.example" .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE {
    ?x foaf:name  ?name ;
       foaf:mbox  ?mbox .
    FILTER isLiteral(?mbox)
}

xsd:boolean  isNUMERIC (RDF term term)

xsd:string  STR (literal literal)
xsd:string  STR (IRI rsrc)

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>

_:a  foaf:name       "Alice".
_:a  foaf:mbox       <mailto:alice@work.example> .

_:b  foaf:name       "Bob" .
_:b  foaf:mbox       <mailto:bob@home.example> .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE {
    ?x foaf:name  ?name ;
      foaf:mbox  ?mbox .
    FILTER regex(str(?mbox), "@work\\.example$")
}

xsd:string  LANG (literal ltrl)

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>

_:a  foaf:name       "Robert"@en.
_:a  foaf:name       "Roberto"@es.
_:a  foaf:mbox       <mailto:bob@work.example> .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?name ?mbox
WHERE {
    ?x foaf:name  ?name ;
       foaf:mbox  ?mbox .
    FILTER ( lang(?name) = "es" )
}

xsd:string  LANGDIR (literal ltrl)

xsd:string  hasLANG (RDF term term)

xsd:string  hasLANGDIR (RDF term term)

iri  DATATYPE (literal literal)

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>
PREFIX eg:         <http://biometrics.example/ns#>
PREFIX xsd:        <http://www.w3.org/2001/XMLSchema#>

_:a  foaf:name       "Alice".
_:a  eg:shoeSize     "9.5"^^xsd:float .

_:b  foaf:name       "Bob".
_:b  eg:shoeSize     "42"^^xsd:integer .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX xsd:  <http://www.w3.org/2001/XMLSchema#>
PREFIX eg:   <http://biometrics.example/ns#>
SELECT ?name ?shoeSize
WHERE { 
    ?x foaf:name  ?name ;
       eg:shoeSize  ?shoeSize .
    FILTER ( datatype(?shoeSize) = xsd:integer )
}

iri  IRI(xsd:string)
iri  IRI(iri)
iri  URI(xsd:string)
iri  URI(iri)

blank node  BNODE()

blank node  BNODE(xsd:string)

literal  STRDT(xsd:string lexicalForm, IRI datatypeIRI)

literal  STRLANG(xsd:string lexicalForm, xsd:string langTag)

literal  STRLANGDIR(xsd:string lexicalForm, xsd:string langTag, xsd:string baseDirection)

iri  UUID()

xsd:string  STRUUID()

xsd:integer  STRLEN(string literal str)

string literal  SUBSTR(string literal source, xsd:integer startingLoc)
string literal  SUBSTR(string literal source, xsd:integer startingLoc, xsd:integer length)

string literal  UCASE(string literal str)

string literal  LCASE(string literal str)

xsd:boolean  STRSTARTS(string literal arg1, string literal arg2)

xsd:boolean  STRENDS(string literal arg1, string literal arg2)

xsd:boolean  CONTAINS(string literal arg1, string literal arg2)

literal  STRBEFORE(string literal arg1, string literal arg2)

literal  STRAFTER(string literal arg1, string literal arg2)

string literal  CONCAT(string literal, ..., string literal)

xsd:boolean  langMatches (xsd:string language-tag, xsd:string language-range)

PREFIX dc:       <http://purl.org/dc/elements/1.1/>

_:a  dc:title         "That Seventies Show"@en .
_:a  dc:title         "Cette Série des Années Soixante-dix"@fr .
_:a  dc:title         "Cette Série des Années Septante"@fr-BE .
_:b  dc:title         "Il Buono, il Bruto, il Cattivo" .

PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT ?title
WHERE {
    ?x dc:title  "That Seventies Show"@en ;
       dc:title  ?title .
    FILTER langMatches( lang(?title), "FR" )
}

PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT ?title
WHERE {
    ?x dc:title  ?title .
    FILTER langMatches( lang(?title), "*" )
}

xsd:boolean  REGEX (string literal text, xsd:string pattern)
xsd:boolean  REGEX (string literal text, xsd:string pattern, xsd:string flags)

PREFIX foaf:       <http://xmlns.com/foaf/0.1/>

_:a  foaf:name       "Alice".
_:b  foaf:name       "Bob" .

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?name
WHERE { 
    ?x foaf:name  ?name
    FILTER regex(?name, "^ali", "i")
}

string literal  REPLACE (string literal arg, xsd:string pattern, xsd:string replacement )
string literal  REPLACE (string literal arg, xsd:string pattern, xsd:string replacement,  xsd:string flags)

xsd:string  ENCODE_FOR_URI(string literal ltrl)

numeric  ABS (numeric term)

numeric  ROUND (numeric term)

numeric  CEIL (numeric term)

numeric  FLOOR (numeric term)

xsd:double  RAND ( )

xsd:dateTime  NOW ()

xsd:integer  YEAR (xsd:dateTime arg)

xsd:integer  MONTH (xsd:dateTime arg)

xsd:integer  DAY (xsd:dateTime arg)

xsd:integer  HOURS (xsd:dateTime arg)

xsd:integer  MINUTES (xsd:dateTime arg)

xsd:decimal  SECONDS (xsd:dateTime arg)

xsd:dayTimeDuration  TIMEZONE (xsd:dateTime arg)

xsd:string  TZ (xsd:dateTime arg)

triple term  TRIPLE (RDF term subj, RDF term pred, RDF term obj)

<<( subj pred obj )>>

VERSION "1.2"
PREFIX : <http://example/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?s ?date {
    ?s ?p ?o .
    BIND( <<( ?s ?p ?o )>> AS ?tt )
    :myreifier rdf:reifies ?tt .
    :myreifier :tripleAdded ?date .
}

VERSION "1.2"
PREFIX : <http://example/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?s ?date {
    ?s ?p ?o .
    BIND( TRIPLE(?s, ?p, ?o) AS ?tt )
    :myreifier rdf:reifies ?tt .
    :myreifier :tripleAdded ?date .
}

RDF term  SUBJECT (triple term triple-term)

RDF term  PREDICATE (triple term triple-term)

RDF term  OBJECT (triple term triple-term)

xsd:boolean  isTRIPLE (RDF term term)

xsd:string  MD5 (xsd:string arg)

xsd:string  SHA1 (xsd:string arg)

xsd:string  SHA256 (xsd:string arg)

xsd:string  SHA384 (xsd:string arg)

xsd:string  SHA512 (xsd:string arg)

SPARQL 导入了 XPath 和 XQuery 函数与运算符 3.1 [XPATH-FUNCTIONS-31] 第 19.1 从 原始类型到原始类型的转换中定义的一部分 XPath 构造器函数。 SPARQL 构造器包括适用于 SPARQL 操作数数据类型的所有 XPath 构造器，以及 RDF 数据模型所施加的 附加数据类型。 SPARQL 中的转换通过在源类型操作数上调用目标类型的构造器函数来执行。

XPath 只定义了从一种 XML Schema 数据类型到另一种数据类型的转换。其余转换 定义如下：

• 将 IRI 转换为 xsd:string 会产生一个 字面量，其词汇值为组成该 IRI 的码位， 且数据类型为 xsd:string。

下表概述始终允许（Y）、 从不允许（N）以及依赖于词汇 值（M）的转换操作。例如，从 xsd:string（第一行）到 xsd:float（第二列）的转换操作 依赖于词汇值（M）。

bool = xsd:boolean
dbl = xsd:double
flt = xsd:float
dec = xsd:decimal
int = xsd:integer
dT = xsd:dateTime
str = xsd:string
IRI = IRI

应注意，任何被指定为在某些条件下返回错误的函数或运算符， 都是有效的扩展点。也就是说，实现可以在这些错误情形中返回 非错误值，并且仍然符合本推荐标准。

PrimaryExpression 文法规则可以是对由 IRI 命名的扩展函数的调用。扩展函数接受若干 RDF 项作为参数，并返回一个 RDF 项。 这些函数的语义由标识该函数的 IRI 标识。

使用扩展函数的 SPARQL 查询可能具有有限的互操作性。

例如，考虑一个名为 func:even 的函数：

xsd:boolean   func:even (numeric value)

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX func: <http://example.org/functions#>
SELECT ?name ?id
WHERE { 
    ?x foaf:name  ?name ;
       func:empId   ?id .
    FILTER (func:even(?id))
}

再举第二个例子，考虑一个计算两点之间距离的函数 aGeo:distance，此处用它查找 Grenoble 附近的地点：

xsd:double   aGeo:distance (numeric x1, numeric y1, numeric x2, numeric y2)

PREFIX aGeo: <http://example.org/geo#>

SELECT ?neighbor
WHERE {
    ?a aGeo:placeName "Grenoble" .
    ?a aGeo:locationX ?axLoc .
    ?a aGeo:locationY ?ayLoc .

    ?b aGeo:placeName ?neighbor .
    ?b aGeo:locationX ?bxLoc .
    ?b aGeo:locationY ?byLoc .

    FILTER ( aGeo:distance(?axLoc, ?ayLoc, ?bxLoc, ?byLoc) < 10 ) .
}

扩展函数可能用于测试核心 SPARQL 规范不支持的某种应用数据类型； 它也可能是在数据类型格式之间进行转换，例如从另一种日期格式 转换为 XSD dateTime RDF 项。

SPARQL 질의의 평가 의미론을 정의하기 위해, SPARQL 질의 문자열의 추상 구문 트리 (SPARQL 문법에 의해 정의됨)는 먼저 SPARQL 대수와 유사한 구문으로 변환됩니다. 이 절은 이 대수 구문에서 형성될 수 있는 표현식을 정의하고, 그런 다음 SPARQL 질의 문자열을 이 대수 구문으로 변환하는 방법을 18.3 대수 구문으로의 변환 절에서 정의합니다.

대수 질의 표현식은 다음과 같이 재귀적으로 정의됩니다.

• 기본 그래프 패턴은 대수 질의 표현식입니다.
• 해 매핑들의 다중집합은 대수 질의 표현식입니다.
• 해 매핑들의 시퀀스는 대수 질의 표현식입니다.
  Issue 231: 해 매핑의 시퀀스와 다중집합을 모두 대수 표현식으로 유지할 것인가? spec:enhancement

  앞의 두 항목이 정말 둘 다 필요한가?
• ContextSolution은 대수 질의 표현식입니다.
• Path(x, ppe, y)는 ppe가 대수 속성 경로 표현식이고, x가 RDF 용어 또는 변수이며, y가 RDF 용어 또는 변수인 경우 대수 질의 표현식입니다.
• Union(A₁, A₂)은 A₁과 A₂가 대수 질의 표현식이면 대수 질의 표현식입니다.
• Join(A₁, A₂)은 A₁과 A₂가 대수 질의 표현식이면 대수 질의 표현식입니다.
• Minus(A₁, A₂)은 A₁과 A₂가 대수 질의 표현식이면 대수 질의 표현식입니다.
• LeftJoin(A₁, A₂, expr)은 A₁과 A₂가 대수 질의 표현식이고 expr가 표현식이면 대수 질의 표현식입니다.
• Filter(expr, A)는 expr가 표현식이고 A가 대수 질의 표현식이면 대수 질의 표현식입니다.
• Extend(A, var, expr)는 A가 대수 질의 표현식이고, var가 변수이며, expr가 표현식이면 대수 질의 표현식입니다.
• Graph(x, A)는 x가 IRI 또는 변수이고 A가 대수 질의 표현식이면 대수 질의 표현식입니다.
• ToMultiset(A)은 A가 대수 질의 표현식이면 대수 질의 표현식입니다.
• ToList(A)는 A가 대수 질의 표현식이면 대수 질의 표현식입니다.
• Group(exprlist, A)은 exprlist가 표현식들의 비어 있지 않은 시퀀스이고 A가 대수 질의 표현식이면 대수 질의 표현식입니다.
• Aggregation(exprlist, func, scalarvals, grp)는 exprlist가 표현식들의 비어 있지 않은 시퀀스이거나 별표 문자(*)이고, func가 집합 함수이며, scalarvals가 부분 함수(빈 함수, 즉 빈 정의역을 가진 함수일 수도 있음)이고, grp가 Group(exprlist', A) 형식의 대수 질의 표현식이면 대수 질의 표현식입니다. 여기서 exprlist'는 표현식들의 시퀀스이고 A는 대수 질의 표현식입니다.
  Issue 230: 'Group'과 'Aggregation'은 대수 구문의 연산자가 아니어야 함 spec:bug

  Group과 Aggregation은 독립적인 연산자가 아니라, AggregateJoin의 정의에 통합되어야 합니다.
• AggregateJoin(A₁, ..., A_n)은 A₁, ..., A_n가 비어 있지 않은 대수 질의 표현식들의 시퀀스(즉, n ≥ 1)이고 이 시퀀스의 모든 표현식 A_i가 Aggregation(exprlist_i, func_i, scalarvals_i, grp_i) 형식이며 앞의 항목에 의해 포착되는 경우 대수 질의 표현식입니다.
• OrderBy(A, condition)은 A가 대수 질의 표현식이고 condition이 정렬 조건이면 대수 질의 표현식입니다.
  Issue 229: "정렬 조건"이라는 개념이 정의되지 않음 spec:bug

  "정렬 조건"이라는 용어는 이 개념의 어떤 정의로 연결되어야 합니다.
• Project(A, PV)는 A가 대수 질의 표현식이고 PV가 변수들의 집합이면 대수 질의 표현식입니다.
• Distinct(A)는 A가 대수 질의 표현식이면 대수 질의 표현식입니다.
• Reduced(A)는 A가 대수 질의 표현식이면 대수 질의 표현식입니다.
• Slice(A, offset) 및 Slice(A, offset, limit)는 A가 대수 질의 표현식이고 offset과 limit가 음이 아닌 정수이면 대수 질의 표현식입니다.

앞의 정의에서 사용된 대수 속성 경로 표현식의 개념은 다음과 같이 재귀적으로 정의됩니다.

• Link(iri)는 iri가 IRI이면 대수 속성 경로 표현식입니다.
• NPS(I)는 I가 IRI들의 비어 있지 않은 집합이면 대수 속성 경로 표현식입니다. NPS는 negated property set의 약어입니다.
• Seq(ppe₁, ppe₂)는 ppe₁과 ppe₂가 대수 속성 경로 표현식이면 대수 속성 경로 표현식입니다.
• Alt(ppe₁, ppe₂)는 ppe₁과 ppe₂가 대수 속성 경로 표현식이면 대수 속성 경로 표현식입니다.
• Inv(ppe)는 ppe가 대수 속성 경로 표현식이면 대수 속성 경로 표현식입니다.
• ZeroOrOnePath(ppe)는 ppe가 대수 속성 경로 표현식이면 대수 속성 경로 표현식입니다.
• ZeroOrMorePath(ppe)는 ppe가 대수 속성 경로 표현식이면 대수 속성 경로 표현식입니다.
• OneOrMorePath(ppe)는 ppe가 대수 속성 경로 표현식이면 대수 속성 경로 표현식입니다.

이 절은 SPARQL 질의 문자열 안의 그래프 패턴과 해 수정자를 대수 질의 표현식으로 변환하는 과정을 정의합니다. 설명된 과정은 중첩된 SELECT 구문을 사용하는 하위 질의가 형성하는 하나의 질의 중첩 수준을 변환하며, 하위 질의에 재귀적으로 적용됩니다. 각 수준은 그래프 패턴 일치와 필터링으로 이루어지고, 그 뒤에 해 수정자가 적용됩니다.

SPARQL 질의 문자열은 파싱되고, 4. SPARQL 구문 절에 제공된 IRI와 트리플 패턴에 대한 축약이 적용됩니다. 이 시점에서 추상 구문 트리는 다음으로 구성됩니다.

OPTIONAL { { ... FILTER ( ... ?x ... ) } }..

Let FS := empty set
For each form FILTER(expr) in the group graph pattern
    FS := FS ∪ {expr}
    End

Let A := undefined
          
For each element G in the GroupOrUnionGraphPattern
    If A is undefined
        A := Translate(G)
    Else
        A := Union(A, Translate(G))
    End

The result is A

If the form is GRAPH IRI GroupGraphPattern
    The result is Graph(IRI, Translate(GroupGraphPattern))

If the form is GRAPH Var GroupGraphPattern
    The result is Graph(Var, Translate(GroupGraphPattern))

Let G := ContextSolution

For each element E in the sequence of elements in the GroupGraphPattern

    If E is of the form OPTIONAL{P} 
        Let A := Translate(P)
        If A is of the form Filter(F, A2)
            G := LeftJoin(G, A2, F)
        Else 
            G := LeftJoin(G, A, true)
            End
        End

    If E is of the form MINUS{P}
        G := Minus(G, Translate(P))
        End

    If E is of the form BIND(expr AS var)
        G := Extend(G, var, expr)
        End

    If E is any other form 
        Let A := Translate(E)
        G := Join(G, A)
        End

   End
   
The result is G.

The result is a multiset data of solution mappings.